[번역]Interaction Based Testing

Spock의 공식문서 중 Interaction Based Testing를 번역해 보았습니다.

보실 때 오역이 있음을 감안하시고, 번역하기에 애매한 부분은 원문 그대로 옮겼습니다.


상호작용 기반 테스팅은 2000년대 초반 Extreme 프로그래밍(XP) 커뮤니티에서 등장한

설계 및 테스팅 기술이다. 그것은 상태가 아닌 객체의 동작에 초점을 맞추고 명세안에서 객체가

메서드 호출을 통해 그들의 협력자들과 어떻게 상호작용 하는지 연구한다.

예를 들어, 구독자에게 메세지를 보내는 게시자가 있다고 가정해보자.

class Publisher {
  List<Subscriber> subscribers = []
  void send(String message){
    subscribers*.receive(message)
  }
}

interface Subscriber {
  void receive(String message)
}

class PublisherSpec extends Specification {
  Publisher publisher = new Publisher()
}

게시자를 어떻게 테스트 할 것인가? 상태기반 테스팅에서는, 게시자가 그의 구독자를 추적하는지

검증 할 수 있다. 더 흥미로운 질문은 게시자가 보낸 메세지를 구독자가 수신하는지 여부이다.

이 질문에 대답하려면, 게시자와 구독자간의 대화를 듣는 구독자의 특별한 구현이 필요하다.

이러한 구현을 mock 객체라고 부른다.

우리는 구독자의 가짜 구현을 손으로 만들 수 있지만,  이 코드를 만들고 유지보수하는 것은

메서드수와 상호작용의 복잡성이 증가함에 따라 괴로워 질 수 있다.

이곳이 mocking framework가 들어오는 곳이다.

그것은 명세안에서 객체와 그들의 협력자 사이의 예상되는 상호작용을 설명하는 방법을

제공하고, 이러한 예상을 검증하는 협력자의 가짜 구현을 만들 수 있다.

가짜 구현은 어떻게 생성되는가?

대부분의 자바 mocking framework와 마찬가지로 Spock은 런타임에 가짜 구현을 만들어내기

위해 JDK dynamic proxies(인터페이스를 mocking할 때)와 CGLIB proxies(클래스를

mocking할 때)를 사용한다.

Groovy  메타 프로그래밍을 기반으로 하는 구현과 비교하면 자바 코드를 테스트할 때도 유용하

다.  자바세계에서는 인기있고 성숙한 mocking framework(JMock, EasyMock, Mockito)이 많

다. 이 도구들 각각은 Spock과 사용할 수 있지만, 우리는 Spock의 명세언어와 긴밀하게 통합된

자체 mocking framework을 사용하기로 결정했다. 이 결정은 Groovy의 모든 기능을 활용하여

상호작용기반 테스트를 보다 더 쉽게 만들고, 더 읽기쉽고, 궁극적으로 더 재미있게 만들려는

의도에서 비롯되었다. 이 장의 끝에서 당신은 이러한 목표를 달성하는 데 동의하게 되기를 바란

다. 표시된 부분을 제외하고, Spock의 mocking framework의 모든 기능은 java 및 Groovy

코드 테스트를 위해 둘다 모두 작동한다.

Creating Mock Objects

Mock 객체는 Mock 메서드로 생성된다. 두개의 가짜 구독자를 만들어보자.

def subscriber = Mock(Subscriber)
def subscriber2 = Mock(Subscriber)

또는 자바와 비슷한 문법이 지원되므로 더 나은 IDE 지원을 제공할 수도 있다.

Subscriber subscriber = Mock()
Subscriber subscriber2 = Mock()

여기 mock 타입은 할당의 왼쪽에 있는 변수 타입으로부터 유추된다.

NOTE | mock 타입이 할당의 왼쪽에서 주어지면 (필수는 아니지만)오른쪽에서는 생략할 수

있다. Mock 객체는 말 그대로 타입을 구현(또는 클래스의 경우 확장)한다. 즉, 우리 예제의

subscriber는 Subscriber이다. 따라서 이 타입을 예상하는 정적타입(Java) 코드로

전달 할 수 있다.


Default Behavior of Mock Objects

Lenient vs. Strict Mocking Frameworks

Mockito에서처럼, 우리는 mocking framework가 기본적으로 관대해야 한다고 믿는다.

이것은 mock 객체에 대한 예상치못한 호출(다른 말로 현재 테스트중인 테스트와 관련없는

상호작용)이 허용되고 기본응답으로 대답함을 의미한다. 반대로, EasyMock 및 JMock 같은

mocking framework는 기본적으로 엄격하고, 예상치 못한 메서드 호출에 예외가 발생한다.

엄격함은 엄함을 강요하지만, 과한 명세로 이어질 수 있고, 결과적으로 다른 내부코드가

변경될때마다 테스트가 깨질 수 있다. Spock의 mocking framework를 사용하면 명세와 관련된

함정을 피하면서 상호작용과 관련된 내용만 쉽게 설명할 수 있다.

초기에 mock객체는 아무런 동작을 하지 않았다. 메서드 호출은 허용했지만 메서드의 리턴타입

(false, 0, 혹은 null)에 대한 기본값을 리턴하는 것외는 아무런 효과가 없었다.예외

는 Object.equals, Object.hashCode, and Object.toString 메서드같은 기본동작을 갖는다.

mock 객체는 그 자체로 동일하고 고유한 해시코드와 그것이 나타내는 타입의 이름을 포함한

문자열 표현을 가진다. 이 기본동작은 메서드를 stubbing하여 재정의할 수 있고,

Stubbing section에서 배울 것이다.


Injecting Mock Objects into Code Under Specification

게시자와 구독자를 만든 후에 우리는 게시자에게 구독자를 알릴 필요가 있다.

class PublisherSpec extends Specification {
  Publisher publisher = new Publisher()
  Subscriber subscriber = Mock()
  Subscriber subscriber2 = Mock()

  def setup() {
    publisher.subscribers << subscriber // << is a Groovy shorthand for List.add()
    publisher.subscribers << subscriber2
  }

이제 두 당사자간의 예상되는 상호작용을 설명할 준비가 되었다.


Mocking

Mocking은 명세하에서 객체와 협력자들 사이의 상호작용을 기술하는 행위이다.

여기 예제가 있다.

def "should send messages to all subscribers"() {
  when:
  publisher.send("hello")

  then:
  1 * subscriber.receive("hello")
  1 * subscriber2.receive("hello")
}

게시자가 ‘hello’ 메세지를 보낼 때, 두 구독자들은 정확히 한번씩 메세지를 받아야 한다.

이 기능 메서드가 실행되면, when block에서 실행 중에 일어난 mock 객체들의 모든

호출이 then: block에서 기술된 상호작용과 일치될 것이다.

상호작용 중 하나가 충족하지 않으면, InteractionNotSatisfiedError가 발생할 것이다.

이 검증은 자동으로 수행되므로 어떤 추가코드도 필요하지 않다.

Interactions

상호작용은 단지 보통의 메서드 호출인가?

그렇지 않다. 상호작용은 보통의 메서드 호출과 유사해 보이지만, 그것은 메서드 호출이 일어날것

으로 예상되는 표현의 방법일 뿐이다. 상호작용에 대한 좋은 생각은 mock 객체로 들어오는

모든 호출과 서로 일치한다는 것이다. 상황에 따라, 상호작용은 0,1 또는 다수의 호출과

일치할 수 있다.

그럼 then: block에 대해 자세히 살펴보자. 두가지 상호작용은 각각 carinality, a target

constraint, a method constraint, an argument constraint 4개의 뚜렷한 파트를

포함한다.
1 * subscriber.receive("hello")
|   |          |       |
|   |          |       argument constraint
|   |          method constraint
|   target constraint
cardinality

Cardinality

상호작용의 cardinality는 얼마나 자주 메서드 호출이 발생할지를 설명한다.

그것은 고정된 번호이거나 범위로 주어질 수 있다.

1 * subscriber.receive("hello")      // exactly one call
0 * subscriber.receive("hello")      // zero calls
(1..3) * subscriber.receive("hello") // between one and three calls (inclusive)
(1.._) * subscriber.receive("hello") // at least one call
(_..3) * subscriber.receive("hello") // at most three calls
_ * subscriber.receive("hello")      // any number of calls, including zero
                                     // (rarely needed; see 'Strict Mocking')

Target Constraint

상호작용의 target constraint는 mock 객체가 어떤 메서드 호출을 받을 것으로 예상되는가를

설명한다.

1 * subscriber.receive("hello") // a call to 'subscriber'
1 * _.receive("hello")          // a call to any mock object

Method Constraint

상호작용의 method constraint는 어떤 메서드가 호출될 것인가를 설명한다.

1 * subscriber.receive("hello") // a method named 'receive'
1 * subscriber./r.*e/("hello")  // a method whose name matches the given regular expression
                                // (here: method name starts with 'r' and ends in 'e')

getter 메서드 호출이 예상될 때, Groovy 속성 구문은 메서드 구문 대신 사용할 수 있다.

1 * subscriber.status // same as: 1 * subscriber.getStatus()

setter 메서드 호출이 예상될 때, 오직 메서드 구문만 사용할 수 있다.

1 * subscriber.setStatus("ok") // NOT: 1 * subscriber.status = "ok"

Argument Constraints

상호작용의 argument constraints는 예상되는 메서드 인자값을 설명한다.

1 * subscriber.receive("hello")     // an argument that is equal to the String "hello"
1 * subscriber.receive(!"hello")    // an argument that is unequal to the String "hello"
1 * subscriber.receive()            // the empty argument list (would never match in our example)
1 * subscriber.receive(_)           // any single argument (including null)
1 * subscriber.receive(*_)          // any argument list (including the empty argument list)
1 * subscriber.receive(!null)       // any non-null argument
1 * subscriber.receive(_ as String) // any non-null argument that is-a String
1 * subscriber.receive({ it.size() > 3 }) // an argument that satisfies the given predicate
                                          // (here: message length is greater than 3)

Argument constraints는 여러개의 인자가 있는 메서드에 대해서도 예상대로 동작한다.

1 * process.invoke("ls", "-a", _, !null, { ["abcdefghiklmnopqrstuwx1"].contains(it) })

vararg 메서드를 다룰 때, 다음과 같은 상호작용에서도 varrag 구문이 사용된다.

interface VarArgSubscriber {
    void receive(String... messages)
}

...

subscriber.receive("hello", "goodbye")
Spock Deep Dive: Groovy Varargs

Groovy는 배열타입의 마지막 파라미터를 vararg style로 호출할 수 있다.따라서,

vararg 구문은 그러한 메서드와 일치하는 상호작용에 사용될 수 있다.

Matching Any Method Call

때때로 임의의 “어떤 것”과 일치할 때 다음과 같은 단어를 쓰면 유용하다.

1 * subscriber._(*_)     // any method on subscriber, with any argument list
1 * subscriber._         // shortcut for and preferred over the above

1 * _._                  // any method call on any mock object
1 * _                    // shortcut for and preferred over the above

(..) * .(*_) >> _는 유효한 상호작용 선언이지만, 특별히 좋은 스타일도 아니다.

Strict Mocking

어떤 메서드 호출과 일치하는 것이 유용할까? 좋은 예는 명시적으로 선언된 것 이외의

상호작용이 허용되지 않는 mocking 스타일의 엄격한 mocking이다.

when:
publisher.publish("hello")

then:
1 * subscriber.receive("hello") // demand one 'receive' call on 'subscriber'
_ * auditing._                  // allow any interaction with 'auditing'
0 * _                           // don't allow any other interaction

0 *은 then: block 또는 메서드의 마지막 상호작용에서 의미가 있다.

모든 호출은 auditing component와 상호작용할 수 있는 _ *를 사용해라

_ * 는 엄격한 mocking의 문맥에서만 의미가 있다. 특히, Stubbing 호출시에는 필요하지 않다.

예를 들어, _ * auditing.record() >> “ok”는 auditing.record() >> “ok”로 할 수 있다.

Where to Declare Interactions

지금까지 우린 then: block에 모든 상호작용을 선언했다. 이는 자연스럽게 스펙을 읽도록 해준다.

그럼에도,  그것들을 만족시키는 상호작용을 when: 블록전에 어느곳이든 넣을 수 있다.

특히, 이것은 상호작용이 setup 메서드에도 선언될 수 있음을 의미한다.

또한 동일한 specification 클래스의 어떤 helper 인스턴스 메서드에도 상호작용을 선언할 수

있다. mock 객체가 상호작용이 일어날 때, 상호작용은 상호작용이 선언된 순서와 일치한다.

만약 호출이 여러 상호작용과 일치한다면, 상위 호출한계에 도달하지 못한 가장 초기에 선언된

상호작용이 승리할 것이다. 이 규칙에 예외가 하나 있다.

then: block에 선언된 상호작용은 다른 상호작용보다 먼저 비교된다.

예를 들어, then block에 선언된 상호작용으로 setup 메서드에서 선언된 상호작용을

오버라이드 할 수 있다.

Spock Deep Dive: How Are Interactions Recognized?

달리 말하면, 정규 메서드 호출이 아니고 상호작용 선언을 표현하는 것이 무엇인가?

Spock은 간단한 구문 규칙으로 상호작용을 인식한다.

즉, 표현식이 statement 위치에 있고, * 또는 right-shift 연산인 경우, 상호작용으로 간주되어

구문 분석됩니다. 그러한 표현은 statement 위치에서 거의 가치가 없으므로, 의미를

바꾸는 것은 좋은 일이 될 것이다.

연산이 cardinality (mocking할 때) 혹은 응답 발생기(stubbing시)를 선언하는 구문과 일치하는

방법에 주목하라. 둘 중 하나는 항상 존재해야 한다.

foo.bar()는 혼자 상호작용으로 간주되지 않을것이다.

Declaring Interactions at Mock Creation Time (New in 0.7)

mock이 변하지 않는 기본 상호작용이 있을경우, mock 생성시 다음과 같이 선언할 수 있다.

def subscriber = Mock(Subscriber) {
   1 * receive("hello")
   1 * receive("goodbye")
}

이 기능은 Stubbing 및 전용 Stubs에 특히 유용하다. 상호작용은 target constraint를

가지지 못한다. 그들이 속한 mock 객체의 문맥에서 명확하다.

상호작용은 mock과 함께 인스턴스 필드를 초기화할 때 선언할 수 있다.

class MySpec extends Specification {
    Subscriber subscriber = Mock {
        1 * receive("hello")
        1 * receive("goodbye")
    }
}

Grouping Interactions with Same Target (New in 0.7)

동일한 대상을 공유하는 상호작용은 Specification.with block에서 그룹화할 수 있다.

Mock 생성시 상호작용 선언과 유사하게, 이것은 target constraint 반복이 불필요하다.

with(subscriber) {
    1 * receive("hello")
    1 * receive("goodbye")
}

with block은 또한 같은 대상에 한해 조건을 그룹화하여 사용할 수 있다.

Mixing Interactions and Conditions

then: block은 상호작용과 조건 둘다 포함한다. 그것이 꼭 필요하지 않더라도, 조건 전에

상호작용을 선언하는 것이 일반적이다.

when:
publisher.send("hello")

then:
1 * subscriber.receive("hello")
publisher.messageCount == 1

publisher가 ‘hello’ 메세지를 보내면, subscriber는 정확히 한번 메세지를 받고,

publisher의 메세지 카운트는 1이 될 것이다.

Explicit Interaction Blocks

내부적으로, Spock은 기능 실행 전 예상되는 상호작용에 대한 완전한 정보를 가지고 있어야한다.

then: block에서 선언된 상호작용이 어떻게 이루어질까? 대답은 when: block 진행전에

곧바로 then: block에 선언된 상호작용으로 이동한다.

대부분 이것은 잘 동작하지만 때때로 문제를 일으킬 수 있다.

when:
publisher.send("hello")

then:
def message = "hello"
1 * subscriber.receive(message)

여기 예상된 인자값을 위한 변수를 선언했다.(혹은 cardinality를 위한 변수선언을 했다)

하지만, Spock은 상호작용이 변수와 본질적으로 연결되어 있다고 말할 만큼 똑똑하지 않다.

그래서 상호작용으로 이동하면 MissingPropertyException이 발생할 것이다.

이 문제를 해결하는 한가지 방법은 when: block전으로 변수 선언을 옮기는 것이다.

(Data Driven Testing에선 변수를 where: block 안으로 옮길 수 있다)

예를 들어, 메세지를 보낼때 같은 변수를 사용하는게 더 이득이다.

다른 해결책은 변수 선언과 상호작용이 함께 속해있다는 사실을 명시하는 것이다.

when:
publisher.send("hello")

then:
interaction {
    def message = "hello"
    1 * subscriber.receive(message)
}

MockingApi.interaction block은 항상 전체적으로 이동하기 때문에, 코드는 정상동작한다.

Scope of Interactions

then: block안에 선언된 상호작용은 when: block 보다 선행된다.

when:
publisher.send("message1")

then:
subscriber.receive("message1")

when:
publisher.send("message2")

then:
subscriber.receive("message2")

이렇게 하면 subscriber가 message1을 수신하는 동안 when: block이 실행되고,

두번째 when: block이 실행되는 동안 message2를 수신받는다.

then: block 밖에 선언된 상호작용은 그들의 선언에서 기능 메서드 끝까지 활성화된다.

상호작용은 항상 특별히 기능 메서드에 범위가 지정된다.

따라서 상호작용은 static 메서드, setupSpec 메서드, cleanupSpec 메서드에는

선언될 수 없다. 달리말하면, mock 객체는 static이나 @Shared 필드에 저장될 수 없다.

Verification of Interactions

mock 기반 테스트가 실패할 수 있는 두 가지 주요 방법이 있다. 상호작용이 허용하는 것보다

더 많거나 더 적은 호출수와 일치할 수 있기 때문이다. 이전 케이스에서는 호출이 일어날 때

바로 감지되어 TooMayInvocationsError가 발생한다.

Too many invocations for:

2 * subscriber.receive(_) (3 invocations)

너무 많은 호출을 쉽게 인지할 수 있도록, Spock은 상호작용과 일치하는 모든 호출을

보여줄 것이다.

Matching invocations (ordered by last occurrence):

2 * subscriber.receive("hello")   <-- this triggered the error
1 * subscriber.receive("goodbye")

output에선, receive(“hello”) 중 하나가 TooManyInvocationsError를 일으켰다.

하나의 라인에 집계된 output으론 두 호출의receive(“hello”)를 구분할 수 없으므로,

receive(“goodbye”) 전에 첫번째 receive(“hello”)에 호출되었을것이다.

두번째 경우,(필요한 것보다 적은 호출의 경우) when block의 실행이 완료된 후

탐지할 수 있다.  (그때까진, 추가적인 호출이 일어날 수 있다)

그것은 TooFewInvocationsError를 발생시킨다.

Too few invocations for:

1 * subscriber.receive("hello") (0 invocations)

메서드가 전혀 호출되지 않았 든, 동일한 메서드가 다른 인자로 호출되었는지,

같은 메서드가 다른 mock 객체에서 호출되었는지 또는 다른 메서드가 이 메서드 대신

호출되었는지 여부는 중요하지 않다.

이 경우 모두 TooFewInvocationsError 에러가 발생합니다.

누락된 호출 대신 일어난 것을 쉽게 진단하기 위해, Spock은 상호작용과 일치하지 않는

상호작용의 유사성으로 정렬해서 모든 호출을 보여줄 것이다.

특별히, 상호작용의 인자를 제외한 모든 것과 일치하는 호출이 먼저 보여질 것이다.

Unmatched invocations (ordered by similarity):

1 * subscriber.receive("goodbye")
1 * subscriber2.receive("hello")

Invocation Order

종종, 정확한 메서드 호출순서는 관련이 없으므로 시간이 흐르면 변한다.

over-specification을 피하기 위해, Spock은 지정된 상호작용이 충족되면 어떤 호출순서도

허용한다.

then:
2 * subscriber.receive("hello")
1 * subscriber.receive("goodbye")

여기서 “hello” “hello” “goodbye”, “hello”, “goodbye” “hello” “goodbye” “hello” “hello”

같은 어떤 호출 순서도 ​​지정된 상호 작용을 충족시킨다.

호출 순서가 중요한 경우 상호 작용을 여러 개의 then: block으로 분할하여 순서를 지정할 수

있다.

then:
2 * subscriber.receive("hello")

then:
1 * subscriber.receive("goodbye")

지금 Spock은 “goodbye” 전에 “hello”가 수신되었는지 검증할 것이다.

달리 말하면, 호출순서는 then: block안이 아니고 사이에 적용된다.

then: block과 and: block을 구분하는 것은 어떤 순서도 적용되지 않는다.

and: 는 오직 문서 목적의 의미만 있고 다른 어떤 의미도 전달하지 않는다.

Mocking Classes

인터페이스 이외에도, Spock은 클래스 mocking을 지원한다. Mocking 클래스는

인터페이스 mocking과 같이 작동한다. 추가로 필요한 것은 cglib-nodep-2.2 혹은 그 이상

그리고 objenesis-1.2나 그 이상을 클래스패스에 넣는 것이다.

이 라이브러리 중 하나가 없다면, Spock은 너에게 부드럽게 알려줄 것이다.

Java8은 CGLIB 3.2.0부터 지원된다.

Stubbing

Stubbing은 협력자들이 메소드 호출에 특정 방식으로 응답하게하는 행위다.

메서드를 stubbing할 때, 메서드를 얼마나 많이 호출했는지 횟수는 신경 쓰지 않아도 됩니다.

호출 될 때마다 특정 값을 반환하거나 일부 부작용을 수행하기만 하면 됩니다.

다음 예제를 위해 구독자의 receive 메서드를 구독자가 메시지를 처리 ​​할 수 ​​있었는지 여부를

알려주는 상태 코드를 반환하도록 수정해보자.

interface Subscriber {
    String receive(String message)
}

이제 receive 메서드는 모든 호출마다 “ok”를 반환할 것이다.

subscriber.receive(_) >> "ok"

subscriber가 메시지를 받을 때마다 ‘ok’로 응답하도록 만들어라.

mocked된 상호작용과 비교해 stubbed 상호작용은 왼쪽 끝에 cardinality가 없지만

오른쪽 끝에 응답 발생기가 추가된다.

subscriber.receive(_) >> "ok"
|          |       |     |
|          |       |     response generator
|          |       argument constraint
|          method constraint
target constraint

stubbed된 상호 작용은 일반적인 위치에서 선언 할 수 있다. 즉,  then: 블록안 또는 when  block

이전에 선언 할 수 있다.  mock 객체가 stubbing에만 사용된다면, setup: block이나

mock 객체 생성시 선언하는 것이 일반적이다.

Returning Fixed Values

우린 이미 right-shift(>>) 연산자로 고정된 값을 반환하는데 사용하는 것을 보았다.

subscriber.receive(_) >> "ok"

다른 호출 시 다른 값을 반환하기 위해, 여러 상호작용을 사용할 수 있다.

subscriber.receive("message1") >> "ok"
subscriber.receive("message2") >> "fail"

이것은 message1을 수신받으면 ok를 반환하고, message2를 수신받으면 fail을 반환할 것이다.

메서드에 선언된 반환 타입과 호환되는 경우, 리턴되는 값에 제한은 없다.

Returning Sequences of Values

성공적인 호출시 다른 값을 반환하기 위해, triple-right-shift 연산자를 사용해라.

subscriber.receive(_) >>> ["ok", "error", "error", "ok"]

이것은 첫번째 호출시 ok를 리턴하고 두번째와 세번째 호출시는 error, 그리고 남은 모든

호출시에는 ok를 리턴할 것이다. 오른쪽은 Groovy가 반복하는 방법을 알아야 한다.

이번 예에서는 일반적인 리스트를 사용했다.

Computing Return Values

메서드의 인자를 기반으로 한 반환값을 계산하려면, closure와 함께 right-shift(>>) 연산자를

사용한다. closure에 타입이 지정되지 않은 단일 파라미터가 선언되면, 메서드의 인자 리스트로

전달한다.

subscriber.receive(_) >> { args -> args[0].size() > 3 ? "ok" : "fail" }

여기선 메세지의 길이가 3을 넘으면 ok, 아니면 fail을 반환한다.

대부분의 경우에 메서드의 인자에 직접 접근하는게 편리하다.

closure가 둘 이상의 파라미터 혹은 단일 타입 파라미터를 선언하면, 메서드 인자는

하나씩 closure 파라미터로 맵핑될 것이다.

subscriber.receive(_) >> { String message -> message.size() > 3 ? "ok" : "fail" }

이 응답기는 전과 동일하게 동작하지만, 틀림없이 읽기가 더 쉽다.

인자보다 메서드 호출에 더 많은 정보가 필요하다면,

org.spockframework.mock.IMockInvacation을 봐라.

이 인터페이스에 선언된 모든 메서드들은 그들 앞에 접두사를 쓸 필요없이 closure 안에서

사용할 수 있다. (Groovy 용어에선, closure는 IMockInvocation의 인스턴스에 위임한다.)

Performing Side Effects

때때로 반환값을 계산하는 것보다 더 필요한 것이 있을 수 있다. 전형적인 예로는

예외를 던지는 것이다. closure는 다음과 같다.

subscriber.receive(_) >> { throw new InternalError("ouch") }

물론, closure는 println 구문같은 더 많은 코드를 포함할 수 있다.

그것은 상호작용과 일치하는 매 호출마다 실행될 것이다.

Chaining Method Responses

메서드 응답은 체이닝할 수 있다.

subscriber.receive(_) >>> ["ok", "fail", "ok"] >> { throw new InternalError() } >> "ok"

이것은 3번째 호출까진 ok, fail, ok를 반환하고, 네번째 호출부터는 InternalError를 던지고

이후 호출에 대해서는 ok를 반환한다.

Combining Mocking and Stubbing

Mocking과 Stubbing은 함께 실행된다.

1 * subscriber.receive("message1") >> "ok"
1 * subscriber.receive("message2") >> "fail"

mocking과 stubbing이 같은 메서드에서 호출될 때, 그들은 같은 상호작용이 일어난다.

특별히, Mockito-style의 stubbing과 두개로 분리된 구문을 mocking하면 작동하지 않는다.

setup:
subscriber.receive("message1") >> "ok"

when:
publisher.send("message1")

then:
1 * subscriber.receive("message1")

상호 작용을 선언하는 곳에서 설명한 것처럼 수신 호출은 먼저 then : 블록의 상호 작용에 대해

일치시킨다. 이 상호 작용은 응답을 지정하지 않으므로 메서드의 반환 유형 (이 경우 null)의

기본값이 반환된다. (이것은 mocking에 대한 Spock의 관대 한 접근 방식의 또 다른 측면이다)

따라서 setup : 블록의 상호 작용은 절대로 일치 할 기회를 얻지 못한다.

동일한 메서드 호출을 Mocking하고 stubbing하는 것은 동일한 상호작용에서 발생해야 한다.

Other Kinds of Mock Objects (New in 0.7)

지금까지 MockingApi.Mock 메서드를 사용하여 mock 객체를 만들었다.

이 메서드외에도, MockingApi 클래스는 mock 객체의 더 특별한 종류를 만들기 위한

여러 다른 팩토리 메서드를 제공한다.

Stubs

stub은 MockingApi.stub 팩토리 메서드에서 만들어진다.

def subscriber = Stub(Subscriber)

mock은 stubbing과 mocking 모두에 사용할 수 있지만, stub은 stubbing에만 사용할 수 있다.

협력자를 stub으로 제한하면 그 역할을 specification의 독자들에게 전달할 수 있다.

stub 호출이 기본적인 상호작용(1 * foo.bar()와 같은)과 일치하면, InvalidException이

발생한다.

mock처럼, stub도 예상치못한 호출을 허용한다. 그렇지만, 그러한 경우에 stub에 의해

반환된 값들은 더 야심찬 것들이다.

  • primitive 타입은 기본타입의 기본값이 반환된다
  • non-primitive 숫자값은(BigDecimal) 0이 반환된다.
  • non-numerical 값들은, 빈값이나 더미객체가 반환된다. 이것은 빈 문자열, 빈 collection
    기본생성자로부터 만들어진 객체, 혹은 기본 값을 반환하는 다른 stub일 수 있다.
    자세한건 org.spockframework.mock.EmptyOrDummyResponse 클래스를 보라.

stub은 종종 고정된 상호작용 세트가 있는 경우가 있다. mock 생성시 상호작용을 선언하는 것이

특히 매력적이다.

def subscriber = Stub(Subscriber) {
    receive("message1") >> "ok"
    receive("message2") >> "fail"
}

Spies

(이 기능을 사용하기 전에 두번 생각해라. 명세에서 코드의 디자인을 바꾸는 것이 더 나을 수 있다.)

spy는 MockingApi.spy factory 메서드로 만들어진다.

def subscriber = Spy(SubscriberImpl, constructorArgs: ["Fred"])

spy는 항상 실제객체를 기반으로 한다. 그래서 특정 생성자 인자와 함께 인터페이스 타입보다

클래스타입을 제공해야 한다.

인자없는 생성자가 제공되면, 타입의 기본 생성자가 사용될 것이다.

 

spy의 메서드 호출은 자동으로 실제 객체에게 위임된다. 마찬가지로, 실제 객체의 메서드로부터

반환된 값들은 spy를 통해 호출자에게 다시 전달된다. spy를 만들고 난 후에는 호출자와

실제객체 사이의 대화를 spy가 들을 수 있다.

1 * subscriber.receive(_)

receive가 정확히 한번 호출되는 것을 제외하고는 publisher와 스파이의 기초를 이루는

SubscriberImpl 객체간 대화는 변경되지 않는다.

spy에서 메서드를 stubbing하면 더 이상 실제 메서드가 호출되지 않는다.

subscriber.receive(_) >> "ok"

SuscriberImpl.receive 호출대신에, receive 메서드는 지금 간단히 “ok”를 반환할 것이다.

때때로, 실제 메서드를 실행하고 위임하는 것이 바람직하다.

subscriber.receive(_) >> { String message -> callRealMethod(); message.size() > 3 ? "ok" : "fail" }

여기선 실제 객체에게 메서드 호출을 위임하는 callRealMethod()를 사용했다.

message 인자값을 주지 않아도 자동으로 전달된다.

callRealMethod()는 실제 상호작용의 결과를 반환하지만, 이번 예에서는 우리가 만든 결과를

반환하기로 결정했다. 실제 메서드에서 다른 메세지를 전달해야 한다면, 우리는

callRealMethodWithArgs(“changed message”)를 사용할 수 있다.

Partial Mocks

(이 기능을 사용하기 전에 두번 생각해라. 명세에서 코드의 디자인을 바꾸는 것이 더 나을 수 있다.)

Spies는 또한 partial mocks를 사용할 수 있다.

// this is now the object under specification, not a collaborator
def persister = Spy(MessagePersister) {
  // stub a call on the same object
  isPersistable(_) >> true
}

when:
persister.receive("msg")

then:
// demand a call on the same object
1 * persister.persist("msg")

Groovy Mocks (New in 0.7)

지금까지 mocking 기능의 모든 것은 자바 혹은 그루비로 만든 것과 상관없이 동일하게 동작한다.

Groovy의 동적기능을 활용하여, Groovy mocks는 Groovy 코드를 테스트하기 위한 몇몇

특별한 부가기능을 제공한다. 그것은 MockingApi.GroovyMock(), MockingApi.GroovyStub()

MockingApi.GroovySpy() factory 메서드에서 만들어진다.

Groovy Mock은 정규 Mock보다 언제 더 좋은가? Groovy mock은 명세 하의 코드가

Groovy로 작성되고 고유한 Groovy mock 기능 중 일부가 필요할 때 사용해야 한다.

Groovy mocks는 Java 코드에서 호출 될 때 일반 mock처럼 작동한다.

명세하의 mocked 타입 코드가 Groovy로 만들어졌다고 Groovy mock을 사용할 필요는 없다.

Groovy mock을 사용해야하는 구체적인 이유가 없다면, 일반적인 mock을 써라.

Mocking Dynamic Methods

모든 Groovy mocks은 GroovyObject의 인터페이스를 구현한다. 그들은 물리적으로

선언된 메서드처럼 동적 메서드의 mocking과 stubbing을 지원한다.

def subscriber = GroovyMock(Subscriber)

1 * subscriber.someDynamicMethod("hello")

Mocking All Instances of a Type

(이 기능을 사용하기 전에 두번 생각해라. 명세에서 코드의 디자인을 바꾸는 것이 더 나을 수 있다.)

보통 Groovy는 일반 mocks와 같은 명세하에서 코드를 주입하는 것이 필요하다.

그럼에도 Groovy mock은 전역으로 생성되면 기능 메서드가 실행되는 동안 mocked된

모든 실제 객체가 자동으로 대체된다.

def publisher = new Publisher()
publisher << new RealSubscriber() << new RealSubscriber()

def anySubscriber = GroovyMock(RealSubscriber, global: true)

when:
publisher.publish("message")

then:
2 * anySubscriber.receive("message")

여기 실제 구독자를 구현한 두 객체와 게시자가 있다.

그때 우린 동일한 타입의 전역 mock을 만들 수 있다. 이것은 실제 구독자들의 모든

메서드 호출을 mock 객체로 변경한다. mock 객체의 인스턴스는 게시자에게 전달되지

않는다. 그것은 상호작용을 설명할때만 사용된다.

global mock은 클래스타입만 생성된다. 기능 메서드가 실행되는 동안 타입의 모든

객체들은 효율적으로 대체된다.

글로벌 mock은 글로벌 효과가 있기 때문에 GroovySpy와 함께 사용하는 것이 편리하다.

이는 상호 작용이 일치하지 않는 한 실제 코드가 실행되도록 해서 객체를 선택적으로 받고

필요한 경우 행동을 변경하도록 한다.

글로벌 Groovy Mock 어떻게 구현되는가?

Global Groovy mocks Groovy 메타 프로그래밍에서 강력한 힘을 얻는다.

보다 정확하게 말하자면, 전역적으로 mocked된 모든 유형에는 기능 메서드의 지속 기간 동안

맞춤 메타 클래스가 할당된다. 글로벌 Groovy mock은 여전히 CGLIB 프록시를 기반으로 하므로

Java 코드에서 호출 될 때 일반적인 mocking 기능 (super power는 아님)을 유지한다.

Mocking Constructors

(이 기능을 사용하기 전에 두번 생각해라. 명세에서 코드의 디자인을 바꾸는 것이 더 나을 수 있다.)

Global mocks는 생성자의 mocking을 지원한다.

def anySubscriber = GroovySpy(RealSubscriber, global: true)

1 * new RealSubscriber("Fred")

spy를 사용하면, 생성자 호출로 반환된 객체는 변하지 않는다.

생성될 객체를 변경하기 위해, 생성자 stub을 사용할 수 있다.

new RealSubscriber("Fred") >> new RealSubscriber("Barney")

일부 코드가 Fred라는 이름으로 subscriber를 만들려고 시도할 때, 우리는 대신 Barney라는

subscriber를 만들것이다.

Mocking Static Methods

(이 기능을 사용하기 전에 두번 생각해라. 명세에서 코드의 디자인을 바꾸는 것이 더 나을 수 있다.)

Global mock은 static 메서드의 mocking과 stubbing을 지원한다.

def anySubscriber = GroovySpy(RealSubscriber, global: true)

1 * RealSubscriber.someStaticMethod("hello") >> 42

동적 메서드에서도 마찬가지로 동작한다.

global mock이 생성자와 static 메서드를 mocking하는데만 사용되는 경우,

mock의 객체는 꼭 필요하지 않다. 이 경우엔 다음과 같이 사용할 수 있다.

GroovySpy(RealSubscriber, global: true)

Advanced Features (New in 0.7)

대부분 이 기능은 필요하지 않다. 하지만 그렇게 해야 한다면 그들을 가질 수 있다.

A la Carte Mocks

Mock (), Stub () Spy () 팩토리 메소드는 특정 구성을 사용하여 mock 객체를 만드는

사용할 있다.  mock 설정보다 세밀한 제어를 원할 경우

org.spockframework.mock.IMockConfiguration 인터페이스를 살펴봐라.

인터페이스 모든 속성은 명명 인자 Mock () 메서드에 전달할 있다. 예를 들어

def person = Mock(name: "Fred", type: Person, defaultResponse: ZeroOrNullResponse, verified: false)

여기서 우리는 Mock () ​​기본 반환 값과 일치하지만 호출이 검증되지 않은(Stub ()처럼)

모의 객체를 만든다.

ZeroOrNullResponse 전달하는 대신 예기치 않은 메서드 호출에 응답하기 위해

자체 customorg.spockframework.mock.IDefaultResponse 제공 ​​ 수 있다.

Detecting Mock Objects

특정객체가 Spock mock 객체인지 확인하려면,

org.spockframework.mock.MockDetector을 사용해라.

def detector = new MockDetector()
def list1 = []
def list2 = Mock(List)

expect:
!detector.isMock(list1)
detector.isMock(list2)

detector는 mock 객체에 대한 더 많은 정보를 얻는데 사용할 수 있다.

def mock = detector.asMock(list2)

expect:
mock.name == "list2"
mock.type == List
mock.nature == MockNature.MOCK
Advertisements

[번역]Spock – Data Driven Testing

Spock의 공식문서 중 Data Driven Testing를 번역해 보았습니다.

보실 때 오역이 있음을 감안하시고, 번역하기에 애매한 부분은 원문 그대로 옮겼습니다.


흔히 다양한 입력 및 예상된 결과로 동일한 테스트 코드를 여러번 실행하는 것이 유용하다.
spock의 데이터 기반 테스팅 지원은 이것을 최고의 기능으로 만든다.

Introduction

Math.max 메서드의 동작을 지정한다고 가정하자:

class MathSpec extends Specification {
  def "maximum of two numbers"() {
    expect:
    // exercise math method for a few different inputs
    Math.max(1, 3) == 3
    Math.max(7, 4) == 7
    Math.max(0, 0) == 0
  }
}

이 접근법은 이와 같이 단순한 경우에는 좋지만, 몇가지 잠재적인 단점이 있다.

  • 코드와 데이터가 섞여 있어 쉽게 독립적으로 변경할 수 없다.
  • 데이터를 외부 소스에서 쉽게 자동생성하거나 가져올 수 없다.
  • 동일한 코드를 여러번 실행하려면, 중복되거나 별도의 메서드로 분리해야 한다.
  • 실패한 경우, 실패를 일으킨 입력값이 무엇인지 바로 알 수 없을 수도 있다.
  • 동일한 코드를 여러번 실행하는 것은 별도의 메서드를 실행하는 것과 동일한 격리로 인해
    이익을 얻지 못한다.

spock의 데이터 기반 테스팅 지원은 이러한 문제를 해결하려고 한다.
시작하려면, 코드를 data-driven feature method로 리팩토링하자.
첫번째, 하드코딩된 integer 값들을 대체할 세개의 메서드 파라미터(데이터 변수라고 불리는)를
소개한다.

class MathSpec extends Specification {
  def "maximum of two numbers"(int a, int b, int c) {
    expect:
    Math.max(a, b) == c
    ...
  }
}

우리는 이 테스트로직을 끝냈지만, 여전히 사용할 데이터 값을 제공할 필요가 있다.
이것은 항상 메서드의 끝에 위치한 where: 블록에서 수행된다.
가장 단순한(가장 일반적인) 경우에, where: 블록은 데이터 테이블이 있다.


Data Tables

데이터 테이블은 고정된 값 집합을 사용하여 기능 메서드를 실행하는 편리한 방법이다.

class MathSpec extends Specification {
  def "maximum of two numbers"(int a, int b, int c) {
    expect:
    Math.max(a, b) == c

    where:
    a | b | c
    1 | 3 | 3
    7 | 4 | 7
    0 | 0 | 0
  }
}

테이블 헤더라 불리는 테이블의 첫번째 행은 데이터 변수를 선언한다. 테이블 행이라 불리는
다음 행은 해당하는 값이 있다. 각 행에 대해 기능 메서드는 한번씩 실행된다.
이것을 메서드의 반복이라 부른다. 반복이 실패하더라도, 나머지 반복은 실행될 것이다.
모든 실패는 보고될 것이다.

데이터 테이블은 적어도 두개의 열이 있어야 한다. 단일 열 테이블은 다음과 같이 작성할 수 있다.:

where:
a | _
1 | _
7 | _
0 | _

Isolated Execution of Iterations

반복은 별도 기능 메서드와 동일한 방법으로 서로 분리된다. 각 반복은 specification class의
자체 인스턴스를 가져오고, setup과 cleanup 메서드는 각각 반복 전후에 호출된다.


Sharing of Objects between Iterations

반복간에 객체를 공유하려면, @Shared 또는 static 필드에 보관해야 한다.

NOTE  | @Shared와 static 변수는 where: 블록내에서 접근할 수 있다.

이러한 객체는 다른 메서드와도 공유된다.  현재 동일한 메서드의 반복 사이에서 객체를 공유하는
좋은 방법은 없다.  이 문제를 고려한다면, 각 메서드를 별도 스펙에 넣는 것을 고려하라, 모든 스펙은
동일한 파일에 보관될 수 있다. 이것은 일부 상용구 코드를 사용하여 더 나은 격리를 얻을 수 있다.


Syntactic Variations

이전 코드는 몇가지 방법으로 조정할 수 있다.
첫째, where: 블록은 이미 모든 데이터 변수를 선언하므로, 메서드 파라미터는 생략할 수 있다.
둘째, 입력과 예상된 출력은 이중 파이프 기호(||)를 사용하여 시각적으로 구분할 수 있다.
이것을 사용하면 코드는 다음과 같이 된다.

class MathSpec extends Specification {
  def "maximum of two numbers"() {
    expect:
    Math.max(a, b) == c

    where:
    a | b || c
    1 | 3 || 3
    7 | 4 || 7
    0 | 0 || 0
  }
}

Reporting of Failures

 max 메서드의 구현에 결함이 있어서 반복 중 하나가 실패한다고 가정하자.

maximum of two numbers   FAILED

Condition not satisfied:

Math.max(a, b) == c
    |    |  |  |  |
    |    7  0  |  7
    42         false

분명한 질문은 어떤 반복이 실패했고 데이터 값은 무엇인가이다. 이 예에서는, 두번째 반복에서
실패했다는 것을 알기가 어렵다. 다른 경우에 이것은 더 어렵거나 불가능할 수도 있다.
어떤 경우엔, spock이 실패를 보고하는 것보다 반복이 실패하는 것을 크고 분명하게 만들면
좋을 것이다. 이것이 @Unrolling 어노테이션의 목적이다.


Method Unrolling

@Unroll로 어노테이션된 메서드는 반복이 독립적으로 보고된다.

@Unroll
def "maximum of two numbers"() {
...
@Unroll이 기본이 아닌 이유는 무엇인가?
@Unroll이 기본이 아닌 한가지 이유는 일부 실행환경(특히 IDEs)은 테스트 메서드의 수를 미리
알려주고 실제 수가 다를 경우 특정문제가 발생하길 기대하기 때문이다.

다른 이유는 @Unroll이 보고된 테스트 수를 크게 바꿀 수 있기 때문이고 이것은 항상 바람직하지 않다.
unrolling은 메서드 실행에 아무런 영향을 주지 않는다. 그것은 단지 보고의 대안일 뿐이다.
실행환경에 따라 출력은 다음과 같다.

maximum of two numbers[0]   PASSED
maximum of two numbers[1]   FAILED

Math.max(a, b) == c
    |    |  |  |  |
    |    7  0  |  7
    42         false

maximum of two numbers[2]   PASSED

이것은 두번째 반복(인덱스 1 포함)이 실패했음을 알려준다. 조금만 더 노력한다면, 더 잘할 수 있다.

@Unroll
def "maximum of #a and #b is #c"() {
...

메서드 이름은 선행 해시 기호(#)로 표시된 placeholders를 사용하여 데이터 변수 a, b 및 c를
나타낸다. 결과에서 placeholders는 구체적인 값으로 변경된다.

maximum of 3 and 5 is 5   PASSED
maximum of 7 and 0 is 7   FAILED

Math.max(a, b) == c
    |    |  |  |  |
    |    7  0  |  7
    42         false

maximum of 0 and 0 is 0   PASSED

이제 우리는 max 메서드 입력 7과 0에 대해 실패한 것을 한 눈에 알 수 있다.
자세한 내용은 More on Unrolled Method Names를 참조하라

@Unroll 어노테이션은 스펙에 배치할 수도 있다. 이는 스펙의 각 데이터 주도 기능 메서드에
배치하는 것과 동일한 효과를 발휘한다.


Data Pipes

데이터 테이블은 데이터 변수에 값을 제공하는 유일한 방법은 아니다. 사실, 데이터 테이블은
하나이상의 데이터 파이프에 대한 syntactic sugar이다.

...
where:
a << [1, 7, 0]
b << [3, 4, 0]
c << [3, 7, 0]

왼쪽 시프트 연산자(<<)로 표시된 데이터 파이프 연산자는 데이터 변수를 데이터 공급자에게 연결한다.
데이터 공급자는 반복마다 하나씩 변수에 대한 모든 값을 보유한다.
반복하는 방법을 알고 있는 Groovy의 어떠한 객체도 데이터 공급자로 사용될 수 있다.
이것은 Collection, String, Iterable 및 Iterable 계약을 구현한 객체를 포함한다.
데이터 공급자가 반드시 데이터일 필요는 없다(Collection의 경우에)
그들은 텍스트 파일, 데이터베이스, 스프레드시트같은 외부 소스에서 데이터를 가져오거나
임의로 데이터를 생성할 수 있다. 데이터 공급자는 필요할 때만(다음 반복전에) 다음 값으로 질문된다.


Multi-Variable Data Pipes

데이터 공급자가 반복당 여러 값(Groovy가 반복하는 방법을 알고 있는 객체)을 반환하면,
동시에 여러 데이터 변수에 연결할 수 있다. 문법은 Groovy multi-assignment와 비슷하지만
왼쪽에는 parentheses 대신 brackets를 사용한다.

@Shared sql = Sql.newInstance("jdbc:h2:mem:", "org.h2.Driver")

def "maximum of two numbers"() {
  expect:
  Math.max(a, b) == c

  where:
  [a, b, c] << sql.rows("select a, b, c from maxdata")
}

관심이 없는 데이터는 밑줄(_)로 무시할 수 있다.

...
where:
[a, b, _, c] << sql.rows("select * from maxdata")

Data Variable Assignment

데이터 변수에는 직접 값을 할당할 수 있다:

...
where:
a = 3
b = Math.random() * 100
c = a > b ? a : b

할당은 모든 반복마다 재평가된다. 위에 표시한 것처럼, 할당의 오른쪽은 다른 데이터 변수를
참조할 수 있다.

...
where:

where:
row << sql.rows("select * from maxdata")
// pick apart columns
a = row.a
b = row.b
c = row.c

Combining Data Tables, Data Pipes, and Variable Assignments

필요에 따라 데이터 테이블, 데이터 파이프 및 변수 할당을 결합할 수 있다.

...
where:
a | _
3 | _
7 | _
0 | _

b << [5, 0, 0]

c = a > b ? a : b

Number of Iterations

반복횟수는 사용가능한 데이터 양에 따라 다르다. 동일한 메서드를 연속적으로 실행하면
반복 횟수가 달라질 수 있다.데이터 공급자의 peer가 다른 값보다 빨리 실행되면,
예외가 발생할 것이다. 변수 할당은 반복횟수에 영향을 주지 않는다.
where: 블록은 할당이 하나만 있으면 정확히 하나의 반복을 만든다.


Closing of Data Providers

모든 반복이 완료된 후, 인자가 없는 close 메서드는 이 메서드가 있는 모든 데이터 제공자에서
호출된다.


More on Unrolled Method Names

 unroll 메서드 이름은 Groovy GString과 비슷하지만, 다음과 같은 차이가 있다.

  • 표현식은 $대신에 #으로 표시되고, ${…} 문법에는 해당되지 않는다.
  • 표현식은 속성 접근 및 인자가 없는 메서드 호출만 지원한다.

이름과 나이 속성을 가진 Person 클래스와 Person 타입의 person 데이터 변수가 주어지면
유효한 메서드 이름은 다음과 같다.

def "#person is #person.age years old"() { // property access
def "#person.name.toUpperCase()"() { // zero-arg method call

위의 #person과 같은 String 아닌 값은 Groovy semantics에 따라 String으로 변환된다.

다음은 잘못된 메서드 이름이다.

def "#person.name.split(' ')[1]" {  // cannot have method arguments
def "#person.age / 2" {  // cannot use operators

필요하다면, 복잡한 표현식을 유지하기 위해 추가 데이터 변수를 도입할 필요가 있다.

def "#lastName"() { // zero-arg method call
  ...
  where:
  person << [new Person(age: 14, name: 'Phil Cole')]
  lastName = person.name.split(' ')[1]
}